sintassi:

• solo per riga o colonna
ricerca per riga o per colonna

riga → =CERCA.X(valore da cercare; colonna di ricerca; colonna con dato da estrarre)
colonna → =CERCA.X(valore da cercare; riga di ricerca; riga con dato da estrarre)


=CERCA.X(valore da cercare; colonna di ricerca; colonna con dato da estrarre;



valore in caso di errore (facoltativo);

tolleranza (facoltativo);

• 0 corrispondenza esatta (impostazione predefinita)
• 1 corrispondenza esatta o immediatamente più grande
• -1 corrispondenza esatta o immediatamente più piccola


• 2 corrispondenza con uso dei caratteri jolly (* ?)

per le ricerche non esatte Fuzzy Lookup con valori simili ma non precisi
in cui i caratteri jolly * ? non bastano
(vedi Power Query - procedure - Fuzzy Lookup)




metodo ricerca (facoltativo))

• 1 ricerca dal primo (impostazione predefinita)
• -1 ricerca dall'ultimo

binarie
si tratta di uno speciale algoritmo che trova la posizione di un valore di ricerca all'interno di un array ordinato confrontandolo con l'elemento centrale dell'array
una ricerca binaria è molto più veloce di una ricerca normale, ma funziona correttamente solo su intervalli ordinati


• 2 ricerca binaria ascendente
• -2 ricerca binaria discendente





esempio: trovo il nome nella tabella con città "Londra"
=CERCA.X("Londra",Tabella[città],Tabella[nome]) primo nome trovato
=CERCA.X("Londra",Tabella[città],Tabella[nome],"errore",0) se non esiste scrive "errore"
=CERCA.X("Londra",Tabella[città],Tabella[nome],"errore",0,-1) ultimo nome trovato (ricerca inziando dalla fine)





esempio: ricerca con uso carattere jolly *
di default la ricerca non accetta caratteri jolly ma cerca proprio quei caratteri senza convertirli in jolly
si usa la tolleranza 2 per utilizzare i caratteri jolly nelle ricerche

E2 =CERCA.X(D2 &"*",Dati[Nome],Dati[Età],"errore") da errore dato che la tolleranza é 0
E3 =CERCA.X(D3 &"*",Dati[Nome],Dati[Età],"errore",2) da 30 usa il carattre jolly *









• sia per riga o colonna
per una ricerca sia per riga che per colonna si usano 2 CERCA.X (XLOOKUP) combinate


=CERCA.X(colonna da cercare,Tabella[#intestazioni tabella],CERCA.X((riga da cercare,Tabella[colonna ricerca],Tabella[#dati]))
=XLOOKUP(H1,Tabella[#Headers],XLOOKUP(G2,Tabella[INDICE],Tabella[#Data]))



esempio: cerchiamo la riga con IND.D e la colonna Colonne 2




=CERCA.X(H1,Tabella[#Headers],XLOOKUP(G2,Tabella[INDICE],Tabella[#Data]))
=XLOOKUP(H1,Tabella[#Headers],XLOOKUP(G2,Tabella[INDICE],Tabella[#Data]))










• con più parametri
é possibile usare una speciale sintassi per fare una ricerca usando più valori di ricerca
ci sono 2 possibilità


• parametri tutti veri E AND
• usando l'operatore * che vuol dire E (AND)
=CERCA.X(1,(Tabella["colonna"]="valore 1")*(Tabella[colonna]="valore 2")*...,Tabella["colonna"])


• concatenamento &
=CERCA.X("valore 1"&"valore 2"&...,Tabella["colonna"]&Tabella["colonna"],Tabella["colonna"])




• solo uno o più parametri tutti veri O OR
usando l'operatore + che vuol dire E (OR)

=CERCA.X(1,(Tabella["colonna"]="valore 1")+(Tabella[colonna]="valore 2")+...,Tabella["colonna"])


puoi anche con le () usare entrambe le due opzioni se necessario
E (O)

=CERCA.X(1,(Tabella["colonna"]="valore 1")*((Tabella[colonna]="valore 2")+(Tabella[colonna]="valore 3")),Tabella["colonna"])




esempio: tabella con nomi e città, da trovare il lavoro in base a due valori in F1 e F2
F3=CERCA.X(1,(Tabella1[Nome]=F1)*(Tabella1[Città]=F2),Tabella1[Lavoro])
F3=XLOOKUP(1,(Tabella1[Nome]=F1)*(Tabella1[Città]=F2),Tabella1[Lavoro])

F4=CERCA.X(F1&F2,Tabella1[Nome]&Tabella1[Città],Tabella1[Lavoro])
F4=XLOOKUP(F1&F2,Tabella1[Nome]&Tabella1[Città],Tabella1[Lavoro])








• utilizzando funzioni
puoi inserire delle funzioni nella lista di ricerca

=CERCA.X(1,funzione(....)="valore",Tabella["colonna"])



esempio: cerco il lavoro del primo nome che inizia per "A"
CERCA.X(1,SINISTRA(Tabella1[Nome],1)="A",Tabella1[Lavoro])
XLOOKUP(1,LEFT(Tabella1[Nome],1)="A",Tabella1[Lavoro])

funzioni precedenti

cerca per riga

• CERCA.VERT (VLOOKUP)
cerca la riga con valore più a sinistra partendo all'alto

sintassi:
=CERCA.VERT(valore parametro di ricerca; intervallo valori; numero colonna valore da cercare; tolleranza[0 nessuna / 1 volere più vicino])




esempio: cerco "ciao" in A e trovo il valore corrispondente in D
=CERCA.VERT("ciao"; A:D; 4; 0)




esempio: cerco nella scheda Foglio2 "ciao" in A e trovo il valore corrispondente in D
=CERCA.VERT("ciao"; Foglio2!A:D; 4; 0)




accetta anche i caratteri jolly * e ?

esempio: cerco valori che hanno "abc" all'interno in A e trovo il valore corrispondente in D
=CERCA.VERT("*abc*"; A:D; 4; 0)




esempio: cerco valori come primo carattere hanno qualunque carattere e proseguono con "abc" all'interno in A e trovo il valore corrispondente in D
=CERCA.VERT("?abc"; A:D; 4; 0)





• INDICE + CONFRONTA (INDEX + MATCH)
é possibile creare una specie di CERCA.VERT che punta anche verso sinistra

sintassi:
INDICE(colonna di ricerca; CONFRONTA(valore; intervallo; tolleranza))




esempio: cerco il valore corrispondente alla scritta sia nella colonna B rispetto alla colonna D
=INDICE(B:B; CONFRONTA("ciao"; D:D; 0))
=INDEX(B:B, MATCH("ciao", D:D, 0))

dal basso verso l'alto

CERCA.VERT cerca il valore dall'alto verso il basso e si ferma al primo valore trovato.
esiste una formula che invece restituisce l'ultimo valore trovato non il primo.

sintassi:
=CERCA(2;1/(Colonnaricerca:Colonnaricerca = valore da cercare); Colonna valore restituito : Colonna valore restituito)




esempio: cerco ciao nella colonna Y e restituisco l'ultimo valore trovato in corrispondenza nella colonna C
=CERCA(2;1/(Y:Y="ciao"); C:C)



si può utilizzare anche per restituire l'ultimo valore o testo di una colonna

esempio: trovo l'ultimo valore inserito nella colonna A
=CERCA(2;1/(1-VAL.VUOTO(A:A)); A:A)

usa CONTA se puoi che é più facile


si può utilizzare anche per restituire l'ultimo valore o testo di una colonna che non da errore

esempio: trovo l'ultimo valore inserito nella colonna A che non da errore
=CERCA(2;1/(1-VAL.ERRORE(A:A)); A:A)

cerca per colonne

• CERCA.ORIZZ (HLOOKUP)
  cerca per colonna in valore più in alto

sintassi:
CERCA.ORIZZ(valore parametro di ricerca; intervallo valori; numero riga valore da cercare,tolleranza[0 nessuna / 1 valore più vicino])





• INDICE + CONFRONTA (INDEX + MATCH)
  anche per il CERCA.ORIZZ é possibile usare INDICE + CONFRONTA

  sintassi:
  INDICE(riga di ricerca; CONFRONTA(valore; intervallo; tolleranza))

  esempio: cerco il valore corrispondente alla scritta della riga 1 rispetto alla riga 4
  =INDICE(A1:Z1; CONFRONTA("ciao"; A4:Z4; 0))
  =INDEX(A1:Z1, MATCH("ciao", A4:Z4, 0))

cerca (non si usa più)

• CERCA (LOOKUP)
  cerca un valore numerico (non funziona con le stringhe) in una colonna o riga e restituisce il valore nella stessa posizione di un'altra colonna o riga
  ATTENZIONE: rispetto a CERCA.VERT e CERCA.ORIZZ non ha il parametro di tolleranza e quindi restituirà sempre il valore puntando quello uguale o quello più basso

  sintassi:
  CERCA(valore parametro di ricerca;intervallo valori;intervallo posizione)

  esempio: cerco 4,19 o il numero subito inferiore nella colonna A da 2 a 6 e restituisco il valore corrispondete nella colonna B
  =CERCA(4,19; A2:A6; B2:B6)